home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Gold Collection
/
Software Vault - The Gold Collection (American Databankers) (1993).ISO
/
cdr50
/
dlreclst.zip
/
DLRECLST.BAS
next >
Wrap
BASIC Source File
|
1993-06-04
|
1KB
|
37 lines
10 CLS
20 PRINT TAB(17);"DELETED PAF INDIV2.DAT AND PAF MARR2.DAT RECORDS"
30 PRINT:PRINT TAB(20);"Created and placed in Public Domain by"
40 PRINT TAB(24);"Jack J. Chandler, 15 Feb. 1991"
50 PRINT:PRINT TAB(26);"Output is to the Printer"
60 PRINT:PRINT:PRINT
70 LINE INPUT "Enter Drive and Path of FR data: "; DP$
80 IF RIGHT$(DP$,1)="\" THEN GOTO 100
90 DP$=DP$+"\"
100 F$=DP$+"INDIV2.DAT"
110 N=11
120 LPRINT TAB(20);"AVAILABLE DELETED INDIV2.DAT RECORDS":LPRINT
130 OPEN "R",1,F$,92
140 FIELD 1,92 AS R$
150 GET 1,1
160 CH$="":FR$=""
170 FOR I=12 TO 21
180 CH$=MID$(R$,I,1)
190 IF CH$>CHR$(32) THEN FR$=FR$+CH$
200 NEXT I
210 NR=VAL(FR$)+1
220 IF NR=1 THEN LPRINT "* NO AVAILABLE DELETED RECORDS *":CLOSE:GOTO 300
230 IF EOF(1) THEN CLOSE 1:GOTO 300
240 GET 1,NR
250 IF MID$(R$,N,1)<>"D" THEN CLOSE :GOTO 300
260 LPRINT NR-1,
270 NR=CVI(MID$(R$,1,2))+1
280 GOTO 230
290 CLOSE
300 IF N=28 THEN CLOSE:LPRINT CHR$(12):END
310 N=28
320 LPRINT:LPRINT TAB(20);"AVAILABLE DELETED MARR2.DAT RECORDS":LPRINT
330 F$=DP$+"MARR2.DAT"
340 OPEN "R",1,F$,28
350 FIELD 1,28 AS R$
360 GOTO 150